AT89C2051+DS1302的红外遥控电子钟汇编程序加了高位灭0功能

ID:75926 · 发表于 2015-4-3 01:20

;DS1302+AT89C2051的LED钟的电路图：

下面是汇编语言源程序：
;遥控器各按键数据码,可根据不同的遥控器修改对应的键码
muteM EQU 10h                ;静音键          闹铃开/关
timerT  EQU 5ch                ;菜单键          进入/退出设置状态
leftL EQU 5fh                ;左移键
rightR  EQU 5bh                ;右移键
upU    EQU 56h                ;增加键
downD EQU 57h                ;减少键
d_off EQU 16H                ;显示键          LED数码管显示/关闭
recall  EQU 44H                ;日历键          DS1302初始化操作
K_on    BIT P3.1             ;闹铃输出
LED1    BIT P3.3
LED2    BIT P3.4
LED3CLK  BIT P3.5             ;DS1302
LED4IO BIT P3.7
RST    BIT P3.0
SECOND  EQU 60H
;60H  秒
;61h  分
;62h  时
;63h  日
;64h  月
;65h  DAY
;66h  年
;6Ah  闹分 from 00(1302)
;6BH  闹时 from 01(1302)
;***************************
      ORG 0000H
      AJMP  START
      ORG 0003H
      LJMP  S_INT          ;IRF
      ORG 000BH          ;200Us
      LJMP  P_INT          ;
      ORG 001BH          ;display LED
      LJMP  DISPLAY
;****************************  ;main program
   ORG 0030H
START: CLR    RST
   MOV SP,#2AH
   SETB 05H
   CLR    06H
   SETB 07H;CLR    07H
   CLR    08H
   CLR    09H
   CLR    0AH
   CLR    0BH
   CLR    0CH
   SETB 0DH
   CLR    0EH
   CLR    0FH
   CLR    10H
   CLR    11H
   MOV R2,#00H          ;
   MOV R3,#00H          ;
   MOV TMOD,#12H
   MOV TL1,#0e5H          ;wait how long to display (20ms)
   MOV TH1,#0BeH
   MOV TH0,#3FH          ;200uS  3f
   MOV TL0,#3FH
   SETB  ET0
   SETB  ET1
   setb  pt0
   SETB  TR0
   SETB  TR1
   SETB  IT0             ;设定INT0触发方式
   SETB  EX0             ;INT0请求中断
   CLR PX0
   ;LCALL SET1302       ;初始化
   MOV R1,#0C1H       ;取定时参数从1302中
   acall T_6061
   MOV 6AH,A          ;M
   MOV R1,#0C3H
   ACALL T_6061
   MOV 6BH,A          ;H
MOV  61H,#0
MOV  62H,#0
   SETB  EA
   sjmp  $
;**********************************
;********************************
DISPLAY: PUSH  ACC
      PUSH  PSW
      MOV TL1,#0e0H       ;wait how long to display (20ms)
      MOV TH1,#0b0H
      mov  dptr,#tab1
      JB 0EH,DIS2
      JB 0FH,DIS3
      JB 10H,DIS4
      JB 11H,DIS5
      JNB 0DH,D_OUT
      JNB 08H,D_GO       ;定时到时，显示闪烁
      JNB 07H,D_OUT
D_GO: MOV DPTR,#TAB1
      MOV A,62H
      ANL A,#0FH
      MOV B,A
      MOV A,62H
      SWAP  A
      ANL A,#07H
      JNZ  MIE    ;判断累加器为零吗？
      MOV A,#0AH    ;累加器为零则就加入灭0功能
  MIE: MOVC  A,@A+DPTR
      MOV P1,A
      CLR LED1
      LCALL DL2M
      SETB  LED1
      MOV A,B
      MOVC  A,@A+DPTR
                  MOV C,07H
                  MOV acc.7,C ;秒灯闪烁
      MOV P1,A
      CLR LED2
      LCALL DL2M
      SETB  LED2
      mov  dptr,#tab2          ;倒装LED字段表
      MOV A,61H
      ANL A,#0FH
      MOV B,A
      MOV A,61H
      SWAP  A
      ANL A,#0FH
      MOVC  A,@A+DPTR
                  MOV C,07H
                  MOV acc.6,C ;秒灯闪烁
      MOV P1,A
      CLR LED3CLK
      LCALL DL2M
      SETB  LED3CLK
      mov  dptr,#tab1
      MOV A,B
      MOVC  A,@A+DPTR
                  MOV C,06H
                  cpl c
                  MOV acc.7,C ;闹铃指示灯
      MOV P1,A
      CLR LED4IO
      LCALL DL2M
      SETB  LED4IO
D_OUT: SETB  TR1
      POP PSW
      POP ACC
      RETI
;*********************
DIS2: AJMP DIS_2
DIS3: AJMP DIS_3
DIS4: AJMP DIS_4
DIS5: AJMP DIS_5
;********************
DIS_2: mov dptr,#tab1          ;显示设置小时
      MOV 6FH,62H
      ACALL BCD_HEX
      MOV B,#10
      DIV AB
      MOVC  A,@A+DPTR
      MOV P1,A
      CLR LED1
      LCALL DL2M
      SETB  LED1
      MOV A,B
      MOVC  A,@A+DPTR
      MOV P1,A
      CLR LED2
      LCALL DL2M
      SETB  LED2
      SETB  TR1
      POP PSW
      POP ACC
      RETI
;*****************
DIS_3: MOV DPTR,#TAB2             ;显示设置分
      MOV 6FH,61H
      ACALL BCD_HEX
      MOV B,#10
      DIV AB
      MOVC  A,@A+DPTR
      MOV P1,A
      CLR LED3CLK
      LCALL DL2M
      SETB  LED3CLK
      MOV A,B
      MOV DPTR,#TAB1
      MOVC  A,@A+DPTR
      MOV P1,A
      CLR LED4IO
      LCALL DL2M
      SETB  LED4IO
      SETB  TR1
      POP PSW
      POP ACC
      RETI
;*****************
DIS_4: mov dptr,#tab1          ;显示设置闹时
      JNB 07H,D4_OUT          ;显示时闪烁
      MOV A,6BH
      MOV B,#0AH
      DIV AB
      MOVC  A,@A+DPTR
      MOV P1,A
      CLR LED1
      LCALL DL2M
      SETB  LED1
      MOV A,B
      MOVC  A,@A+DPTR
      MOV P1,A
      CLR LED2
      LCALL DL2M
      SETB  LED2
D4_OUT:  SETB  TR1
      POP PSW
      POP ACC
      RETI
;***********************
DIS_5: MOV DPTR,#TAB2
      JNB 07H,D5_OUT             ;显示时闪烁
      MOV A,6AH                ;显示设置闹分
      MOV B,#0AH
      DIV AB
      MOVC  A,@A+DPTR
      MOV P1,A
      CLR LED3CLK
      LCALL DL2M
      SETB  LED3CLK
      MOV DPTR,#TAB1
      MOV A,B
      MOVC  A,@A+DPTR
      MOV P1,A
      CLR LED4IO
      LCALL DL2M
      SETB  LED4IO
D5_OUT:  SETB  TR1
      POP PSW
      POP ACC
      RETI
;*****************************
DL2M: MOV 43H,#14H          ;how long display every LED(2ms)
DL2:    MOV 44H,#14H
DL1:    NOP
      NOP
      DJNZ 44H,DL1
      DJNZ 43H,DL2
      RET
;************************定时读取1302时间及判断闹铃时间是否到*******
P_INT: PUSH  ACC
      PUSH  PSW
      INC R2
      CJNE  R2,#250D,P_OUT
      MOV R2,#00H
      INC R3
      CJNE  R3,#10D,P_OUT
      MOV R3,#00H
      CPL 07H
      MOV P1,#0FFH
      ACALL R_1302
OUT:    JNB 06H,P_OUT
      MOV A,6BH
      MOV B,#10
      DIV AB
      SWAP  A
      ADD A,B
      CJNE  A,62H,PP_OUT
      MOV A,6AH
      MOV B,#10
      DIV AB
      SWAP  A
      ADD A,B
      CJNE  A,61H,PP_OUT
      SETB  08H             ;定时到标志
      MOV C,07H
      cpl c
      MOV K_ON,C
P_OUT: POP PSW
      POP ACC
      RETI
PP_OUT:  SETB  K_ON
      CLR 08H
      POP PSW
      POP ACC
      RETI
;************************有接收到遥控器信号*******
S_INT:CLR EA
   PUSH ACC
   PUSH PSW
   PUSH DPH
   PUSH DPL
   PUSH 02H
   PUSH 03H
   MOV R6,#10D ;10个880微秒-->9毫秒
SB: ACALL  YS1
   JB    P3.2,EXIT
   DJNZ R6, SB
   JNB P3.2, $ ;等待9毫秒低电平引导脉冲完
   ACALL  YS2    ;延时4.74毫秒判断是否有后续脉冲
   JB    P3.2,EXIT
   MOV R1,#1AH ;将32位代码分别放在1AH/1BH/1CH/1DH中
   MOV R2,#4D
PP: MOV R3,#8D
JJJJ: JNB P3.2,$
   ACALL  YS1
   MOV C,P3.2
   JNC UUU
   JB    P3.2,$
UUU:  MOV A,@R1
   RRC A
   MOV @R1,A
   DJNZ R3,JJJJ
   INC R1
   DJNZ R2,PP
;-------------------------------------
   MOV  A,1AH    ;进行代码识别
   XRL  A,#40h    ;判断1AH的值是否等于遥控器低8位地址（40h）
   JNZ  EXIT    ;如果不同则无效退出
   MOV  A,1bH
   XRL  A,#0bfh ;再判断高8位地址是否正确（0bfh）
   JNZ  EXIT
   MOV  A,1CH
   CPL  A
   XRL  A,1DH    ;将1CH的值取反后和1DH比较不同则无效丢弃（核对数据是否准确）
   JNZ  EXIT
   ACALL DO       ;相应按键的处理
EXIT: SETB EA
   POP  03H
   POP  02H
   POP  DPL
   POP  DPH
   POP  PSW
   POP  ACC
   RETI
;--------------------delay-----------------------
YS1:  MOV 70H,#16D ;延时880微秒
D1: MOV 71H,#21D
   DJNZ 71H,$
   DJNZ 70H,D1
   RET
YS2:  MOV 70H,#09D ;延时4740微秒
D2: MOV 71H,#220D
   DJNZ 71H,$
   DJNZ 70H,D2
   RET
;---------------------------------------------------------
TAB: DB 00H,01H,02H,03H,04H,05H,06H,07H,08H,09H    ;TAB1  LED数码管显示表 TAB遥控器键值表（未用）
;TAB1:  DB 3FH,11H,5EH,5BH,71H,6BH,6FH,19H,7FH,7bH,77H,7CH,39H,5EH,79H,71H
tab1:  DB  0C0H,0F9H,0a4h,0b0h,99h,92h,82h,0f8h,80h,90h,0FFH
TAB2:  DB  0c0H,0f9H,64H,70H,59H,52H,42H  ;倒装LED段码表
;0CH 为设置标志，0DH为全显示标志，0EH为显示设置小时标志，0FH为显示设置分标志
;10H 为显示设置闹时标志，11H为显示设置闹分标志
;增加闹时静音功能
;mute-10h,timer-0eh,left-46h,right-47h,up-19h,down-1dh
DO:    MOV    A,1CH
      CJNE A,#TIMERT,REDO  ;代码不是设置/退出键
      JNB    0CH,SET1       ;是，则进入
      CLR    0CH          ;是，已经进入，则退出
      SETB 0DH          ;恢复正常显示
      CLR    0EH
      CLR    0FH
      CLR    10H
      CLR    11H
      RET
SET1: SETB 0CH
      SETB 0EH
      CLR    0DH
      CLR    0FH
      CLR    10H
      CLR    11H
      RET
REDO: CJNE A,#MUTEM,REDO1  ;不是设置键的处理REDO1,2,3,4...
      LJMP MUTE          ;MUTE?
REDO1:  CJNE A,#D_OFF,DO_SET2
      LJMP DIS_OFF       ;关闭显示
DO_SET2:JB    0CH,SET2       ;时间设置的处理
      RET
SET2: CJNE A,#UPU,SET2A
      LJMP INC1          ;+加(^)
SET2A:  CJNE A,#DOWND,SET2B
      LJMP DEC2          ;- 减
SET2B:  CJNE A,#RIGHTR,SET2C
      LJMP RIGHT          ;RIGHT右移(>)
SET2C:  CJNE A,#LEFTL,SET2D
      LJMP LEFT          ;LEFT左移(<)
SET2D:  CJNE A,#RECALL,SET2EXT ;DS1302初始化
      LJMP SET1302
SET2EXT:RET
;--------------------------------INC------------------------
INC1: JB    0EH,INCH
      JB    0FH,INCM
      JB    10H,INC_H
      JB    11H,INC_M
      RET
INC_H:  INC    6BH             ;闹钟小时增加
      MOV    A,6BH
      CJNE A,#24D,INCH3
      MOV    6BH,#0
INCH3:  MOV    R1,#0C2H
      MOV    R0,6BH
      ACALL SETONE          ;并写入DS1302
      RET
INC_M:  INC    6AH             ;闹钟分增加
      MOV    A,6AH
      CJNE A,#60D,INCH4
      MOV    6AH,#0
INCH4:  MOV    R1,#0C0H
      MOV    R0,6AH
      ACALL SETONE          ;并写入DS1302
      RET
INCH: ;INC    62H             ;小时增加
      MOV    6FH,62H
      ACALL BCD_HEX
      INC    A
      CJNE A,#24D,INCH1
      MOV    A,#0
INCH1:  MOV    6FH,A
      ACALL HEX_BCD
      MOV    62H,A
      MOV    R1,#84H
      MOV    R0,62H
      ACALL SETONE          ;并写入DS1302
      RET
INCM: ;INC    61H             ;分增加
      MOV    6FH,61H
      ACALL BCD_HEX
      INC    A
      CJNE A,#60D,INCH2
      MOV    A,#0
INCH2:  MOV    6FH,A
      ACALL HEX_BCD
      MOV    61H,A
      MOV    R1,#82H
      MOV    R0,61H
      ACALL SETONE          ;并写入DS1302
      RET
;----------------------------------DEC----------------------
DEC2: JB    0EH,DECH
      JB    0FH,DECM
      JB    10H,DEC_H
      JB    11H,DEC_M
      RET
DECH: MOV    6FH,62H
      ACALL BCD_HEX
      DEC    A
      CJNE A,#0FFH,DECH1
      MOV    A,#23
DECH1:  MOV    6FH,A
      ACALL HEX_BCD
      MOV    62H,A
      MOV    R1,#84H
      MOV    R0,62H
      ACALL SETONE
      RET

DECM: MOV    6FH,61H
      ACALL BCD_HEX
      DEC    A
      CJNE A,#0FFH,DECM1
      MOV    A,#59
DECM1:  MOV    6FH,A
      ACALL HEX_BCD
      MOV    61H,A
      MOV    R1,#82H
      MOV    R0,61H
      ACALL SETONE
      RET
DEC_H:  DEC    6BH
      MOV    A,6BH
      CJNE A,#0FFH,DECH3
      MOV    6BH,#23D
DECH3:  MOV    R1,#0C2H
      MOV    R0,6BH
      ACALL SETONE
      RET
DEC_M:  DEC    6AH
      MOV    A,6AH
      CJNE A,#0FFH,DECH4
      MOV    6AH,#59D
DECH4:  MOV    R1,#0C0H
      MOV    R0,6AH
      ACALL SETONE
      RET
;--------------------------------RIGHT----------------------
RIGHT:  JB    0EH,RIGHT1
      JB    0FH,RIGHT2
      JB    10H,RIGHT3
      JB    11H,RIGHT4
      RET                      ;右移
RIGHT1: CLR    0EH
      SETB 0FH
      RET
RIGHT2: CLR    0FH
      SETB 10H
      RET
RIGHT3: CLR    10H
      SETB 11H
      RET
RIGHT4: CLR    11H
      SETB 0EH
      RET
;--------------------------------LEFT-----------------------
LEFT: JB    0EH,LEFT1
      JB    0FH,LEFT2
      JB    10H,LEFT3
      JB    11H,LEFT4
      RET                      ;左移
LEFT1:  SETB 11H
      CLR    0EH
      RET
LEFT2:  SETB 0EH
      CLR    0FH
      RET
LEFT3:  SETB 0FH
      CLR    10H
      RET
LEFT4:  SETB 10H
      CLR    11H
      RET
;------------------------------MUTE--------------
MUTE: setb k_ON
      CPL    06H             ;静音
      CLR    08H
      RET
;-----------------------------DISPLAY OFF--------
DIS_OFF:CLR    ET1
      CPL    05H
      JNB    05H,REDORE
      SETB ET1
REDORE: RET
;------------------------------------初始化1302-------------------------
SET1302: CLR RST          ;2002年1月1日12:00:00
      CLR LED3CLK
      MOV    SECOND,#0
      MOV    61H,#0
      MOV    62H,#18    ;18(D)=12(BCD)
      MOV    63H,#1
      MOV    64H,#1
      MOV    65H,#1
      MOV    66H,#2
      SETB RST
      MOV A,#8EH
      LCALL  R_BIT
      MOV A,#00H
      LCALL  R_BIT
      SETB LED3CLK
      CLR RST
      MOV R0,#SECOND
      MOV R7,#7
      MOV R1,#80H
SET1302A:CLR RST
      CLR LED3CLK
      SETB RST
      MOV A,R1
      LCALL  R_BIT
      MOV A,@R0
      LCALL  R_BIT
      INC R0
      INC R1
      INC R1
      SETB LED3CLK
      CLR RST
      DJNZ R7,SET1302A
      CLR RST
      CLR LED3CLK
      sETB LED3CLK
      nop
      CLR RST
      nop
      clr led3clk
      SETB RST
      MOV A,#90H
      LCALL  R_BIT
      MOV A,#10100101B       ;充电器设置
      LCALL  R_BIT
      SETB LED3CLK
      CLR RST
      CLR LED3CLK
      SETB RST
      MOV A,#8EH
      LCALL  R_BIT
      MOV A,#80H
      LCALL  R_BIT
      SETB LED3CLK
      CLR RST
      RET
;----------------------读取一RAM R1为地址------
T_6061:  CLR RST
      CLR LED3CLK
      SETB RST
      MOV A,R1
      LCALL  R_BIT
      LCALL  W_BIT
      SETB LED3CLK
      CLR RST
      RET
;-----------------------------
R_1302:  MOV R0,#SECOND
      MOV R7,#7
      MOV R1,#81H
R_1302A: CLR RST
      CLR LED3CLK
      SETB RST
      MOV A,R1
      LCALL  R_BIT
      LCALL  W_BIT
      MOV @R0,A
      INC R0
      INC R1
      INC R1
      SETB LED3CLK
      CLR RST
      DJNZ R7,R_1302A
      RET
;------------------R_BIT------------------
R_BIT: MOV R4,#8
R_BIT1:  RRC A
      MOV LED4IO,C
      SETB LED3CLK
      CLR LED3CLK
      DJNZ R4,R_BIT1
      RET
;-------------------W_BIT-----------------------
W_BIT: MOV R4,#8
W_BIT1:  MOV C,LED4IO
      RRC A
      SETB LED3CLK
      CLR LED3CLK
      DJNZ R4,W_BIT1
      RET
;------------------------进制转换--------------------------
BCD_HEX:
      MOV A,6FH
      ANL A,#0FH
      MOV B,A
      MOV A,6FH
      MOV 6FH,B
      SWAP A
      ANL A,#0FH
      MOV B,#0AH
      MUL AB
      ADD A,6FH
      ;MOV 6FH,A
      RET
HEX_BCD:
      MOV A,6FH
      MOV B,#10
      DIV AB
      SWAP  A
      ADD A,B
      ;MOV 6FH,A
      RET
;-----写一地址---R1 为地址，R0 为数据----------
SETONE:  CLR LED3CLK
      CLR RST
      CLR LED3CLK
      NOP
      SETB RST
      MOV A,#8EH
      LCALL  R_BIT
      MOV A,#00H
      LCALL  R_BIT
      SETB LED3CLK
      CLR RST
      CLR LED3CLK
      NOP
      CLR RST
      CLR LED3CLK
      SETB RST
      MOV A,R1
      LCALL  R_BIT
      MOV A,R0
      LCALL  R_BIT
      NOP
      SETB LED3CLK
      CLR RST
      NOP
      NOP
      CLR RST
      CLR LED3CLK
      SETB RST
      MOV A,#8EH
      LCALL  R_BIT
      MOV A,#80H
      LCALL  R_BIT
      SETB LED3CLK
      CLR RST
      RET
  END

ID:487884 · 发表于 2019-4-4 18:27

真的很好啊

ID:101531 · 发表于 2016-11-20 21:51

真心的学习了,谢谢分享

ID:61140 · 发表于 2015-10-13 06:05

纯属跑过,不过你做的确实很好,努力

ID:86421 · 发表于 2015-10-12 21:11

真心的学习了

ID:86205 · 发表于 2015-7-20 04:59

不错哦。真心

ID:75461 · 发表于 2015-4-6 13:06

谢谢分享

ID:75926 · 发表于 2015-4-3 01:22

//打开DS1302充电二级管一个二级管串联一个2K电阻
#include <REGX51.H>
//#include "ds1302.h"
#define leddata P2
#define sec 0x80
#define min 0x82
#define hou 0x84
#define read 0x01
sbit MODE=P1^6;
sbit SET=P1^5;
sbit UP=P1^4;
sbit DOWN=P1^3;
sbit led0=P0^7;
sbit led1=P0^6;
sbit led2=P0^5;
sbit led3=P0^3;
sbit led4=P0^2;
sbit led5=P0^1;
sbit T_CLK=P1^2;
sbit T_IO =P1^1;
sbit T_RST=P1^0;
sbit ACC0=ACC^0;
sbit ACC7=ACC^7;
//******************************************************
sbit den_cuo=P3^3; //这是一个小夜灯的控制引脚
sbit den_kai_guan=P3^2;
//********DS1302读写程序***************
/********************************************************************
函数名：RTInputByte()
功能：实时时钟写入一字节
说明：往DS1302写入1Byte数据 (内部函数)
入口参数：d 写入的数据
返回值：无
***********************************************************************/
void RTInputByte(unsigned char d)
{
unsigned char i;
ACC = d;
for(i=8; i>0; i--)
{
T_IO = ACC0; //相当于汇编中的 RRC
T_CLK = 1;
T_CLK = 0;
ACC = ACC >> 1;
}
}
/********************************************************************
函数名：RTOutputByte()
功能：实时时钟读取一字节
说明：从DS1302读取1Byte数据 (内部函数)
入口参数：无
返回值：ACC
设计：zhaojunjie 日期：2002-03-19
修改：日期：
***********************************************************************/
unsigned char RTOutputByte(void)
{
unsigned char i;
for(i=8; i>0; i--)
{
ACC = ACC >>1; //相当于汇编中的 RRC
ACC7 = T_IO;
T_CLK = 1;
T_CLK = 0;
}
return(ACC);
}
/********************************************************************
函数名：Write1302()
功能：往DS1302写入数据
说明：先写地址，后写命令/数据 (内部函数)
调用：RTInputByte() , RTOutputByte()
入口参数：ucAddr: DS1302地址, ucData: 要写的数据
返回值：无
***********************************************************************/
void Write1302(unsigned char ucAddr, unsigned char ucDa)
{
T_RST = 0;
T_CLK = 0;
T_RST = 1;
RTInputByte(ucAddr); // 地址，命令
RTInputByte(ucDa); // 写1Byte数据
T_CLK = 1;
T_RST = 0;
}
/********************************************************************
函数名：Read1302()
功能：读取DS1302某地址的数据
说明：先写地址，后读命令/数据 (内部函数)
调用：RTInputByte() , RTOutputByte()
入口参数：ucAddr: DS1302地址
返回值：ucData :读取的数据
***********************************************************************/
unsigned char Read1302(unsigned char ucAddr)
{
unsigned char ucData;
T_RST = 0;
T_CLK = 0;
T_RST = 1;
RTInputByte(ucAddr); // 地址，命令
ucData = RTOutputByte(); // 读1Byte数据
T_CLK = 1;
T_RST = 0;
return(ucData);
}
/********************************************************************
函数名：Set1302()
功能：设置初始时间
说明：先写地址，后读命令/数据(寄存器多字节方式)
调用：Write1302()
入口参数：pClock: 设置时钟数据地址格式为: 秒分时日月星期年
7Byte (BCD码)1B 1B 1B 1B 1B 1B 1B
返回值：无
***********************************************************************/
void Set1302(unsigned char *pClock)
{
unsigned char i;
unsigned char ucAddr = 0x80;
Write1302(0x8e,0x00); // 控制命令,WP=0,写操作
for(i =7; i>0; i--)
{
Write1302(ucAddr,*pClock); // 秒分时日月星期年
pClock++;
ucAddr +=2;
}
Write1302(0x8e,0x80); // 控制命令,WP=1,写保护
}
void delays(unsigned char);
void display(void);
void Scan_Key(void);
void id_case1_key();
void Set_id(unsigned char ,unsigned char);
unsigned char hour,minute,second,id=0,timecount,re_disp=0;
bit flag;
unsigned char code tab[]={ 0x9F,/*0*/
0x12,/*1*/
0x2F,/*2*/
0x3B,/*3*/
0xB2,/*4*/
0xB9,/*5*/
0xBD,/*6*/
0x13,/*7*/
0xBF,/*8*/
0xBB,/*9*/
};
unsigned char inittime[7]={0x00,0x00,0x12,0x16,0x11,0x06,0x04};
// 秒分钟小时日月年星期
void t0(void) interrupt 1 using 0
{
TH0=(65535-50000)/256; //50ms定时
TL0=(65535-50000)%256;
timecount++;re_disp++;
if(timecount>9)
{
timecount=0;
flag=~flag;
}
if(re_disp>200){re_disp=0;if(id)id=0;}
}
void delays(unsigned char k)
{
unsigned char i,j;
for(i=0;i<k;i++)
for(j=0;j<50;j++);
}
void display(void)
{
if(flag&hour)
{
led0=0;leddata=0x00;delays(10);led0=1; //这句中的0xff是数码管的灭码
led1=0;leddata=0x00&~((unsigned char)~flag<<6);delays(10);led1=1; //这句中的0xff是数码管的灭码
}
else
{
leddata=tab[Read1302(hou+1)/16];led0=0;delays(10);led0=1;
leddata=tab[Read1302(hou+1)%16]&~((unsigned char)~flag<<6);led1=0;delays(10);led1=1;
}
if(flag&minute)
{
led2=0;leddata=0x00&~((unsigned char)~flag<<6);delays(10);led2=1;
led3=0;leddata=0x00&~((unsigned char)~flag<<6);delays(10);led3=1;
}
else
{
leddata=tab[Read1302(min+1)/16]&~((unsigned char)~flag<<6);led2=0;delays(10);led2=1;
leddata=tab[Read1302(min+1)%16]&~((unsigned char)~flag<<6);led3=0;delays(10);led3=1;
}
if(flag&second)
{
led4=0;leddata=0x00&~((unsigned char)~flag<<6);delays(10);led4=1;
led5=0;leddata=0x00;delays(10);led5=1;
}
else
{
leddata=tab[Read1302(sec+1)/16]&~((unsigned char)~flag<<6);led4=0;delays(10);led4=1;
leddata=tab[Read1302(sec+1)%16];led5=0;delays(10);led5=1;
}
}
void Scan_Key(void)
{
display();
if(!SET)
{
while(!SET)display();
re_disp=0;
id++;if(id>3)id=0;
}
if(id==0){hour=0;minute=0;second=0;}
if(id==1){hour=1;id_case1_key();}
if(id==2){hour=0;minute=1;id_case1_key();}
if(id==3){minute=0;second=1;id_case1_key();}
}
void id_case1_key(void)
{
display();
if (!DOWN) //减少
{
while(!DOWN)display();
re_disp=0;
Set_id(id,0);
}
if (!UP) //增加
{
while(!UP)display();
re_disp=0;
Set_id(id,1);
}
}
//根据选择调整相应项目并写入DS1302
void Set_id(unsigned char sel,unsigned char sel_1)
{
signed char max,mini,address,item;
if(sel==1) {address=hou; max=23;mini=0;} //小时
if(sel==2) {address=min; max=59;mini=0;} //分钟
if(sel==3) {address=sec; max=0;mini=0;} //秒
item=Read1302(address+1)/16*10+Read1302(address+1)%16;
if (sel_1==0) item--; else item++;
if(item>max) item=mini;
if(item<mini) item=max;
Write1302(0x8e,0x00);//允许写操作
Write1302(address,item/10*16+item%10);
Write1302(0x8e,0x80);//写保护，禁止写操作
}
void main()
{
den_cuo=0;
TMOD=0x01;
TH0=(65535-50000)/256;
TL0=(65535-50000)%256;
EA=1;
ET0=1;
TR0=1;
Write1302(0x90,0xa5);//打开充电二级管一个二级管串联一个2K电阻
Write1302(0x8e,0x80);//写保护，禁止写操作
if(!UP&!DOWN)Set1302(inittime);
while(1)
{
Scan_Key();
if(Read1302(hou+1)==0x18) //小夜灯每天晚上18点时自动点亮
{
den_cuo=1;
}
if(Read1302(hou+1)==0x07) //小夜灯每天早上7点时自动熄灭
{
den_cuo=0;
}
if(den_kai_guan==0)
{
delays(50);
if(den_kai_guan==0)
{
while(!den_kai_guan);
den_cuo=!den_cuo;
}
}
}
}

复制代码

帐号		自动登录	找回密码
密码			立即注册

AT89C2051+DS1302的红外遥控电子钟汇编程序 加了高位灭0功能

相关帖子

AT89C2051+DS1302的红外遥控电子钟汇编程序加了高位灭0功能